// OLED_I2C_ViewFont
// Copyright (C)2019 Rinky-Dink Electronics, Henning Karlsen. All right reserved
// web: http://www.RinkyDinkElectronics.com/
//
// **********************************************
// *** This demo is for 128x64 pixel displays ***
// **********************************************
//
// A quick demo of how to use my OLED_I2C library.
//
// Remember to use external pull-up resistors on the data and clock signals
// if they are required.
//
// You can connect the OLED display to any available pin. The library will
// use the Wire library for display communication.

#include <Wire.h>                                       // Подключаем библиотеку Wire
#include <ESP8266WiFi.h>                                // Подключаем библиотеку ESP8266WiFi
#include <NTPClient.h>
#include <WiFiUdp.h>

#include <Adafruit_BME280.h>                            // Подключаем библиотеку Adafruit_BME280
#include <Adafruit_Sensor.h>

#define SDA D2
#define SCL D1

#include <OLED_I2C.h>

OLED  myOLED(SDA, SCL);           // SDA - D2, SCL - D1  для дисплея

// задайте константу для своей временной зоны (часового пояса)
const long utcOffsetInSeconds = 32400;      // time zone +9 (Chita):  9*60*60=32400

// Дни недели ВСК, ПНД, ВТР, СРД, ЧТВ, ПТН, СБТ
char daysOfTheWeek[7][12] = {"DCR", "GYL", "DNH", "CHL", "XND", "GNY", "C<N"};  

// Определение NTP-клиента для получения времени
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org", utcOffsetInSeconds);

const char* ssid = "********";                   // Название Вашей WiFi сети
const char* password = "************";     // Пароль от Вашей WiFi сети

extern uint8_t SmallFont[];
extern uint8_t RusFont[];
extern uint8_t MediumNumbers[];

Adafruit_BME280 bme;

void setup()
{
  Serial.begin(9600);

  if (!bme.begin(0x76)) {                               // Проверка инициализации датчика
    Serial.println("Could not find a valid BME280 sensor, check wiring!");   // Печать об ошибке
    while (1);                                          // Зацикливаем
  }

  if (!myOLED.begin(SSD1306_128X64))
  {
    Serial.println("Failed memory allocation...");
    while (1);  // In case the library failed to allocate enough RAM for the display buffer...
  }

  myOLED.setFont(RusFont);

  Serial.print("Connecting to ");                       // Отправка в Serial port
  Serial.println(ssid);                                 // Отправка в Serial port
  WiFi.begin(ssid, password);                           // Подключение к WiFi Сети
  while (WiFi.status() != WL_CONNECTED) {               // Проверка подключения к WiFi сети
    delay(500);                                         // Пауза
    Serial.print(".");                                  // Отправка в Serial port
  }

  Serial.println("");                                   // Отправка в Serial port
  Serial.println("WiFi connected.");                    // Отправка в Serial port
  Serial.print("IP address: ");                       // Отправка в Serial port
  Serial.println(WiFi.localIP());                       // Отправка в Serial port

  timeClient.begin();
}

void loop()
{

  timeClient.update();

  Serial.print(daysOfTheWeek[timeClient.getDay()]);
  Serial.print(", ");
  Serial.print(timeClient.getHours());

  Serial.print(":");
  Serial.print(timeClient.getMinutes());

  Serial.print(":");
  Serial.println(timeClient.getSeconds());
  //Serial.println(timeClient.getFormattedTime());

  float tempC = bme.readTemperature();
  float humidity = bme.readHumidity();
  float pressuremmHg = bme.readPressure() * 0.007500616;    // перевод атм. давления Pa в mmHg

  myOLED.clrScr();
  myOLED.setFont(RusFont);
 
// Вывод на дисплей дня недели тремя символами на русском
  myOLED.print(daysOfTheWeek[timeClient.getDay()], LEFT, 13);     
  myOLED.setFont(MediumNumbers);

  // Вывод на дисплей показаний времени (часы и минуты)
  myOLED.print(String(timeClient.getHours()) + "-" + String(timeClient.getMinutes()), CENTER, 6 );
  myOLED.setFont(RusFont);

  myOLED.print("Ntvgthfnehf", LEFT, 28);     // Температура
  myOLED.print("Dkf;yjcnm", LEFT, 40);     // Влажность
  myOLED.print("Lfdktybt", LEFT, 52);     // Давление
  myOLED.setFont(SmallFont);

  Serial.println(bme.readTemperature());                  // Печать температуры
  myOLED.print(String(tempC) + " *C", RIGHT, 28);       // Вывод на дисплей температуры
  myOLED.print(String(humidity) + " %", RIGHT, 40);     // Вывод на дисплей влажности
  myOLED.print(String(pressuremmHg) + " mmHg", RIGHT, 52);    // Вывод на дисплей давления в мм рт. ст.
  myOLED.update();
  delay (5000);

}